Даны массивы
GAI1, GAI2, …, GAI20 – шифры 20 ГАИ,
DTP1, DTP2, …, DTP20 – количество дорожно-транспортных происшествий за месяц по каждому ГАИ.
Построить три массива:
1 – шифры ГАИ, у которых количество ДТП = 0,
2 – шифры ГАИ, у которых количество ДТП ≤ 10,
3 – шифры ГАИ, у которых количество ДТП ≤ 80.
program ThreeNewArrays;
const
MAX_ARRAY_SIZE = 20;{константа - максимальный размер массивов "Шифр" и "ДТП"}
NEW_ARRAYS = 3;{количество новых заполняемых массивов}
MAX_SHIFR = 30;{максимальное значение шифра для генерации}
MAX_DTP = 100;{максимальное количество дтп}
MAX_LIMITS : array[ 1..NEW_ARRAYS ] of integer = ( 0, 10, 80 );{верхние границы для выборки}
type
TShifr = array[ 1..MAX_ARRAY_SIZE ] of integer;{тип - шифр}
TDTP = array[ 1..MAX_ARRAY_SIZE ] of integer;{тип - количество дтп}
procedure GenerateRandomShifrArray( var shifr : TShifr; maxValue : integer );
{процедура генерирует массив неповторяющихся шифров}
var
i, j : integer;{i, j - счетчики}
begin
for i := 1 to MAX_ARRAY_SIZE do{для каждого элемента массива}
begin
repeat
shifr[ i ] := random( maxValue );{присваиваем случайное значение шифра}
j := i - 1;{далее будем проверять все предыдущие шифры, чтобы не было дубликатов}
while( ( j >= 1 ) and ( shifr[ i ] <> shifr[ j ] ) ) do{смотрим до начала массива и ищем дубликаты}
dec( j );{переход к предудущему элементу}
until j = 0;{если дошли до конца массива - дубликатов нет, иначе весь цикл rereat повторяется}
end;
end;
procedure GenerateRandomDTPArray( var dtp : TDTP; maxValue : integer );
{процедура генерирует случайные значения дтп}
var
i : integer;{счетчик}
begin
for i := 1 to MAX_ARRAY_SIZE do{для каждого элемента массива}
dtp[ i ] := random( maxValue );{заполняем случайным значением}
end;
procedure InputShifrArray( var shifr : TShifr );
{процедура ввода массива шифров}
var
i : integer;{счетчик}
begin
for i := 1 to MAX_ARRAY_SIZE - 1 do{для каждого элемента массива, кроме последнего}
read( shifr[ i ] );{читаем очередной шифр}
readln( shifr[ MAX_ARRAY_SIZE ] );{читаем последний шифр с переходом на новую строку}
end;
procedure InputDTPArray( var dtp : TDTP );
{процедура ввода массива количества ДТП}
var
i : integer;{счетчик}
begin
for i := 1 to MAX_ARRAY_SIZE - 1 do{для каждого элемента массива, кроме последнего}
read( dtp[ i ] );{читаем очередной элемент}
readln( dtp[ MAX_ARRAY_SIZE ] );{читаем последний элемент с переходом на новую строку}
end;
procedure PrintInfo( var shifr : TShifr; var dtp : TDTP );
{функция печати пары шифр - кол-во ДТП}
var
i : integer;{счетчик}
begin
for i := 1 to MAX_ARRAY_SIZE do{для каждой пары}
writeln( 'Shifr [', shifr[ i ], '] - ', dtp[ i ] );{печать очередной пары}
end;
procedure PrintShifrArray( var shifr : TShifr; elements : integer );
{процедура печати массива шифров из elements элементов}
var
i : integer;{счетчик}
begin
for i := 1 to elements do{для каждого элемента}
write( shifr[ i ], ' ' );{печать элемента и разделителя - пробел}
writeln;{переход на следующую строку}
end;
function GenerateNewArrayByDTPLimit( var newShifr : TShifr; var shifr : TShifr; var dtp : TDTP; maxLimit : integer ) : integer;
{функция генерации нового массива шифров по имеющимся массивам шифра и кол-ва дтп, а также верхней границы ДТП - maxLimit}
var
i : integer;{счетчик}
begin
GenerateNewArrayByDTPLimit := 0;{инициализация результата - кол-во элементов в новом массиве}
for i := 1 to MAX_ARRAY_SIZE do{просматриваем все входящие элементы}
if ( dtp[ i ] >= 0 ) and ( dtp[ i ] <= maxLimit ) then{сравниваем по условию задачи}
begin
inc( GenerateNewArrayByDTPLimit );{увеличиваем количество элементов в новом массиве}
newShifr[ GenerateNewArrayByDTPLimit ] := shifr[ i ];{запоминаем подходящий элемент}
end;
end;
var
shifr : TShifr;{начальный массив шифров}
dtp : TDTP;{начальный массив кол-ва ДТП}
newShifrElements : array[ 1..NEW_ARRAYS ] of integer;{массив для хранения информации о количестве элементов в сгенерированных массивах}
newShifr : array[ 1..NEW_ARRAYS ] of TShifr;{массивы для генерации}
i : integer;{счетчик}
begin
randomize;
writeln( 'Generate GAI shifrs...' );
GenerateRandomShifrArray( shifr, MAX_SHIFR );{заполняем массив шифров случайными значениями}
writeln( 'Generate DTPs...' );
GenerateRandomDTPArray( dtp, MAX_DTP );{заполняем массив кол-ва ДТП случайными значениями}
writeln( 'Source data...' );{печать исходных данных}
PrintInfo( shifr, dtp );{печать исходных массивов}
for i := 1 to NEW_ARRAYS do
begin
newShifrElements[ i ] := GenerateNewArrayByDTPLimit( newShifr[ i ], shifr, dtp,MAX_LIMITS[ i ] );{генерируем новый массив по условию задачи}
writeln( 'Generated array with dtp <= ', MAX_LIMITS[ i ], ' :' );
PrintShifrArray( newShifr[ i ], newShifrElements[ i ] );{печать сгенерированного массива}
end;
readln;{ожидаем ввода}
end.
|
Главная
Каталог файлов
